RFE: Add workflow that checks all products to see if they are close

to a user configured level, and email a group to let them know that
they are close to being out of stock.

lib/WebGUI/Workflow/Activity/NotifyAboutLowStock.pm

@@ -0,0 +1,141 @@
+package WebGUI::Workflow::Activity::NotifyAboutLowStock;
+
+
+=head1 LEGAL
+
+ -------------------------------------------------------------------
+  WebGUI is Copyright 2001-2008 Plain Black Corporation.
+ -------------------------------------------------------------------
+  Please read the legal notices (docs/legal.txt) and the license
+  (docs/license.txt) that came with this distribution before using
+  this software.
+ -------------------------------------------------------------------
+  http://www.plainblack.com                     info@plainblack.com
+ -------------------------------------------------------------------
+
+=cut
+
+use strict;
+use base 'WebGUI::Workflow::Activity';
+use WebGUI::International;
+use WebGUI::Asset::Sku::Product;
+use WebGUI::Inbox;
+
+=head1 NAME
+
+Package WebGUI::Workflow::Activity::NotifyAboutUser
+
+=head1 DESCRIPTION
+
+Takes a user object and sends out a message. Can use macros in message, to and subject
+fields.
+
+=head1 SYNOPSIS
+
+See WebGUI::Workflow::Activity for details on how to use any activity.
+
+=head1 METHODS
+
+These methods are available from this class:
+
+=cut
+
+
+#-------------------------------------------------------------------
+
+=head2 definition ( session, definition )
+
+See WebGUI::Workflow::Activity::defintion() for details.
+
+=cut 
+
+sub definition {
+	my $class = shift;
+	my $session = shift;
+	my $definition = shift;
+	my $i18n = WebGUI::International->new($session, "Workflow_Activity_NotifyAboutLowStock");
+	push(@{$definition}, {
+		name=>$i18n->get("activityName"),
+		properties=> {
+			warningLimit => {
+				fieldType=>"integer",
+				label=>$i18n->get("warning limit"),
+				defaultValue=>42,
+				hoverHelp=>$i18n->get("warning limit help"),
+				},
+			toGroup => {
+				fieldType=>"group",
+				label=>$i18n->get("group to notify"),
+				defaultValue=>3,
+				hoverHelp=>$i18n->get("group to notify help"),
+				},
+			subject => {
+				fieldType=>"text",
+				label=>$i18n->get("subject", 'Asset_DataForm'),
+				defaultValue=>'',
+				hoverHelp=>$i18n->get("subject help", 'Asset_DataForm'),
+				},
+			}
+		});
+	return $class->SUPER::definition($session,$definition);
+}
+
+
+#-------------------------------------------------------------------
+
+=head2 execute ( [ object ] )
+
+See WebGUI::Workflow::Activity::execute() for details.
+
+=cut
+
+sub execute {
+	my ($self, undef, $instance) = @_;
+	my $message         = $instance->getScratch('LowStockMessage') || '';
+	my $counter         = $instance->getScratch('LowStockLast')    || 0;
+	my $belowThreshold  = $instance->getScratch('LowStockBelow')   || 0;
+    my $productIterator = WebGUI::Asset::Sku::Product->getIsa($self->session, $counter);
+    my $warningLimit = $self->get('warningLimit');
+    my $finishTime = time() + $self->getTTL;
+    my $expired = 0;
+    PRODUCT: foreach my $product ($productIterator->()) {
+        VARIANT: foreach my $collateral ( @{ $product->getAllCollateral('variantsJSON') }) {
+            if ($collateral->{quantity} <= $warningLimit) {
+                ##Build message
+                $belowThreshold = 1;
+                $message .= $product->getUrl(sprintf 'func=editVariant;vid=%s', $collateral->{variantId})
+                         .  "\n";
+            }
+        }
+        $counter++;
+        ##Time check and set flag
+        if (time() > $finishTime) {
+            $expired = 1;
+            last PRODUCT;
+        }
+    }
+    ##If timer expired, then store message and limit and release
+    if ($expired) {
+        $instance->setScratch('LowStockMessage', $message);
+        $instance->setScratch('LowStockLast',    $counter);
+        $instance->setScratch('LowStockBelow',   $belowThreshold);
+        return $self->WAITING;
+    }
+
+    $instance->deleteScratch('LowStockMessage');
+    $instance->deleteScratch('LowStockLast');
+    $instance->deleteScratch('LowStockBelow');
+    if ($belowThreshold) {
+        my $inbox = WebGUI::Inbox->new($self->session);
+        $inbox->addMessage({
+            status  => 'completed',
+            subject => $self->get('subject'),
+            groupId => $self->get('toGroup'),
+            message => $message,
+        });
+    }
+
+    return $self->COMPLETE;
+}
+
+1;

lib/WebGUI/i18n/English/Workflow_Activity_NotifyAboutLowStock.pm

@@ -0,0 +1,38 @@
+package WebGUI::i18n::English::Workflow_Activity_NotifyAboutLowStock;
+use strict;
+
+our $I18N = {
+
+	'activityName' => {
+		message => q|Notify About Low Stock|,
+		context => q|The name of this workflow activity.|,
+		lastUpdated => 0,
+	},
+
+	'warning limit' => {
+		message => q|Warning Limit|,
+		context => q|Field label in the edit Workflow Activity screen.|,
+		lastUpdated => 0,
+	},
+
+	'warning limit help' => {
+		message => q|When a variant of a product has less than this amount, you will be warned.|,
+		context => q|Hover help in the edit Workflow Activity screen.|,
+		lastUpdated => 0,
+	},
+
+	'group to notify' => {
+		message => q|Group to notify|,
+		context => q|Label in the edit Workflow Activity screen.|,
+		lastUpdated => 0,
+	},
+
+	'group to notify help' => {
+		message => q|Group to notify|,
+		context => q|Hover help in the edit Workflow Activity screen.|,
+		lastUpdated => 0,
+	},
+
+};
+
+1;